28allday
83c6b62c13
Convert remaining reachable surfaces to NsIcon (launcher, utilities, windowinfo,
sidebar, dashboard, notification toast, shared controls IconTextButton/Menu/
SplitButton/ToggleButton/CollapsibleSection/CustomSpinBox, CoverArt). Handles
the `sourceComponent: MaterialIcon {` form and icon-via-alias controls.
- IconTextButton: alias -> plain `icon` property + bound NsIcon (cross-file alias
to a custom property was rejected).
- Reverted IconButton `font:` (the controls-wide font->fontStyle sweep wrongly
hit ButtonBase, which uses font not fontStyle).
- Glyphs map: +31 names (dashboard/utilities/launcher leftovers) — no "?" glyphs.
Old collapsed bar + old lock sub-components left as-is (unused, never render).
Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
102 lines
2.9 KiB
QML
102 lines
2.9 KiB
QML
import QtQuick
|
|
import Caelestia.Config
|
|
import qs.components
|
|
import qs.services
|
|
import qs.modules.launcher.services
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property Schemes.Scheme modelData
|
|
required property var list
|
|
|
|
implicitHeight: Tokens.sizes.launcher.itemHeight
|
|
|
|
anchors.left: parent?.left
|
|
anchors.right: parent?.right
|
|
|
|
StateLayer {
|
|
radius: Tokens.rounding.large
|
|
onClicked: root.modelData?.onClicked(root.list)
|
|
}
|
|
|
|
Item {
|
|
anchors.fill: parent
|
|
anchors.leftMargin: Tokens.padding.medium
|
|
anchors.rightMargin: Tokens.padding.medium
|
|
anchors.margins: Tokens.padding.small
|
|
|
|
StyledRect {
|
|
id: preview
|
|
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
|
|
border.width: 1
|
|
border.color: Qt.alpha(`#${root.modelData?.colours?.outline}`, 0.5)
|
|
|
|
color: `#${root.modelData?.colours?.surface}`
|
|
radius: Tokens.rounding.full
|
|
implicitWidth: parent.height * 0.8
|
|
implicitHeight: parent.height * 0.8
|
|
|
|
Item {
|
|
anchors.top: parent.top
|
|
anchors.bottom: parent.bottom
|
|
anchors.right: parent.right
|
|
|
|
implicitWidth: parent.implicitWidth / 2
|
|
clip: true
|
|
|
|
StyledRect {
|
|
anchors.top: parent.top
|
|
anchors.bottom: parent.bottom
|
|
anchors.right: parent.right
|
|
|
|
implicitWidth: preview.implicitWidth
|
|
color: `#${root.modelData?.colours?.primary}`
|
|
radius: Tokens.rounding.full
|
|
}
|
|
}
|
|
}
|
|
|
|
Column {
|
|
anchors.left: preview.right
|
|
anchors.leftMargin: Tokens.spacing.medium
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
|
|
width: parent.width - preview.width - anchors.leftMargin - (current.active ? current.width + Tokens.spacing.medium : 0)
|
|
spacing: 0
|
|
|
|
StyledText {
|
|
text: root.modelData?.flavour ?? ""
|
|
font: Tokens.font.body.medium
|
|
}
|
|
|
|
StyledText {
|
|
text: root.modelData?.name ?? ""
|
|
font: Tokens.font.body.small
|
|
color: Colours.palette.m3outline
|
|
|
|
elide: Text.ElideRight
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
id: current
|
|
|
|
asynchronous: true
|
|
anchors.right: parent.right
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
|
|
active: `${root.modelData?.name} ${root.modelData?.flavour}` === Schemes.currentScheme
|
|
|
|
sourceComponent: NsIcon {
|
|
icon: "check"
|
|
color: Colours.palette.m3onSurfaceVariant
|
|
fontStyle: Tokens.font.icon.large
|
|
}
|
|
}
|
|
}
|
|
}
|