3710df29f5
* feat: reorder bar, no popout yet * chore: cleanup * refactor: use DelegateChooser * feat: popouts * chore: cleanup * better popout check + fix async stuff + bar interaction + a bunch of other fixes * fix activewindow and bar vertical padding * readme: add config opt * bar: fix top/bottom padding * bar: better wheel behaviour --------- Co-authored-by: 2 * r + 2 * t <61896496+soramanew@users.noreply.github.com>
100 lines
2.7 KiB
QML
100 lines
2.7 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import qs.components
|
|
import qs.services
|
|
import qs.utils
|
|
import qs.config
|
|
import QtQuick
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property var bar
|
|
required property Brightness.Monitor monitor
|
|
property color colour: Colours.palette.m3primary
|
|
|
|
readonly property int maxHeight: {
|
|
const otherModules = bar.children.filter(c => c.id && c.item !== this && c.id !== "spacer");
|
|
const otherHeight = otherModules.reduce((acc, curr) => acc + curr.height, 0);
|
|
// Length - 2 cause repeater counts as a child
|
|
return bar.height - otherHeight - bar.spacing * (bar.children.length - 1) - bar.vPadding * 2;
|
|
}
|
|
property Title current: text1
|
|
|
|
clip: true
|
|
implicitWidth: Math.max(icon.implicitWidth, current.implicitHeight)
|
|
implicitHeight: icon.implicitHeight + current.implicitWidth + current.anchors.topMargin
|
|
|
|
MaterialIcon {
|
|
id: icon
|
|
|
|
anchors.horizontalCenter: parent.horizontalCenter
|
|
|
|
animate: true
|
|
text: Icons.getAppCategoryIcon(Hyprland.activeToplevel?.lastIpcObject.class, "desktop_windows")
|
|
color: root.colour
|
|
}
|
|
|
|
Title {
|
|
id: text1
|
|
}
|
|
|
|
Title {
|
|
id: text2
|
|
}
|
|
|
|
TextMetrics {
|
|
id: metrics
|
|
|
|
text: Hyprland.activeToplevel?.title ?? qsTr("Desktop")
|
|
font.pointSize: Appearance.font.size.smaller
|
|
font.family: Appearance.font.family.mono
|
|
elide: Qt.ElideRight
|
|
elideWidth: root.maxHeight - icon.height
|
|
|
|
onTextChanged: {
|
|
const next = root.current === text1 ? text2 : text1;
|
|
next.text = elidedText;
|
|
root.current = next;
|
|
}
|
|
onElideWidthChanged: root.current.text = elidedText
|
|
}
|
|
|
|
Behavior on implicitHeight {
|
|
NumberAnimation {
|
|
duration: Appearance.anim.durations.normal
|
|
easing.type: Easing.BezierSpline
|
|
easing.bezierCurve: Appearance.anim.curves.emphasized
|
|
}
|
|
}
|
|
|
|
component Title: StyledText {
|
|
id: text
|
|
|
|
anchors.horizontalCenter: icon.horizontalCenter
|
|
anchors.top: icon.bottom
|
|
anchors.topMargin: Appearance.spacing.small
|
|
|
|
font.pointSize: metrics.font.pointSize
|
|
font.family: metrics.font.family
|
|
color: root.colour
|
|
opacity: root.current === this ? 1 : 0
|
|
|
|
transform: Rotation {
|
|
angle: 90
|
|
origin.x: text.implicitHeight / 2
|
|
origin.y: text.implicitHeight / 2
|
|
}
|
|
|
|
width: implicitHeight
|
|
height: implicitWidth
|
|
|
|
Behavior on opacity {
|
|
NumberAnimation {
|
|
duration: Appearance.anim.durations.normal
|
|
easing.type: Easing.BezierSpline
|
|
easing.bezierCurve: Appearance.anim.curves.standard
|
|
}
|
|
}
|
|
}
|
|
}
|