51 lines
1.4 KiB
QML
51 lines
1.4 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import "lock"
|
|
import Quickshell
|
|
import Quickshell.Wayland
|
|
import Caelestia.Config
|
|
import Caelestia.Internal
|
|
import qs.services
|
|
|
|
Scope {
|
|
id: root
|
|
|
|
required property Lock lock
|
|
readonly property bool enabled: !GlobalConfig.general.idle.inhibitWhenAudio || !Players.list.some(p => p.isPlaying)
|
|
|
|
function handleIdleAction(action: var): void {
|
|
if (!action)
|
|
return;
|
|
|
|
if (action === "lock")
|
|
lock.lock.locked = true;
|
|
else if (action === "unlock")
|
|
lock.lock.locked = false;
|
|
else if (typeof action === "string")
|
|
Hypr.dispatch(action);
|
|
else
|
|
Quickshell.execDetached(action);
|
|
}
|
|
|
|
LogindManager {
|
|
onAboutToSleep: {
|
|
if (GlobalConfig.general.idle.lockBeforeSleep)
|
|
root.lock.lock.locked = true;
|
|
}
|
|
onLockRequested: root.lock.lock.locked = true
|
|
onUnlockRequested: root.lock.lock.unlock()
|
|
}
|
|
|
|
Variants {
|
|
model: GlobalConfig.general.idle.timeouts
|
|
|
|
IdleMonitor {
|
|
required property var modelData
|
|
|
|
enabled: root.enabled && (modelData.enabled ?? true)
|
|
timeout: modelData.timeout
|
|
respectInhibitors: modelData.respectInhibitors ?? true
|
|
onIsIdleChanged: root.handleIdleAction(isIdle ? modelData.idleAction : modelData.returnAction)
|
|
}
|
|
}
|
|
}
|