28allday
83c6b62c13
Convert remaining reachable surfaces to NsIcon (launcher, utilities, windowinfo,
sidebar, dashboard, notification toast, shared controls IconTextButton/Menu/
SplitButton/ToggleButton/CollapsibleSection/CustomSpinBox, CoverArt). Handles
the `sourceComponent: MaterialIcon {` form and icon-via-alias controls.
- IconTextButton: alias -> plain `icon` property + bound NsIcon (cross-file alias
to a custom property was rejected).
- Reverted IconButton `font:` (the controls-wide font->fontStyle sweep wrongly
hit ButtonBase, which uses font not fontStyle).
- Glyphs map: +31 names (dashboard/utilities/launcher leftovers) — no "?" glyphs.
Old collapsed bar + old lock sub-components left as-is (unused, never render).
Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
89 lines
2.4 KiB
QML
89 lines
2.4 KiB
QML
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Widgets
|
|
import Caelestia.Config
|
|
import qs.components
|
|
import qs.services
|
|
import qs.utils
|
|
import qs.modules.launcher.services
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property DesktopEntry modelData
|
|
required property DrawerVisibilities visibilities
|
|
|
|
implicitHeight: Tokens.sizes.launcher.itemHeight
|
|
|
|
anchors.left: parent?.left
|
|
anchors.right: parent?.right
|
|
|
|
StateLayer {
|
|
radius: Tokens.rounding.large
|
|
onClicked: {
|
|
Apps.launch(root.modelData);
|
|
root.visibilities.launcher = false;
|
|
}
|
|
}
|
|
|
|
Item {
|
|
anchors.fill: parent
|
|
anchors.leftMargin: Tokens.padding.medium
|
|
anchors.rightMargin: Tokens.padding.medium
|
|
anchors.margins: Tokens.padding.small
|
|
|
|
IconImage {
|
|
id: icon
|
|
|
|
asynchronous: true
|
|
source: Quickshell.iconPath(root.modelData?.icon, "image-missing")
|
|
implicitSize: parent.height * 0.8
|
|
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
}
|
|
|
|
Item {
|
|
anchors.left: icon.right
|
|
anchors.leftMargin: Tokens.spacing.medium
|
|
anchors.verticalCenter: icon.verticalCenter
|
|
|
|
implicitWidth: parent.width - icon.width - favouriteIcon.width
|
|
implicitHeight: name.implicitHeight + comment.implicitHeight
|
|
|
|
StyledText {
|
|
id: name
|
|
|
|
text: root.modelData?.name ?? ""
|
|
font: Tokens.font.body.medium
|
|
}
|
|
|
|
StyledText {
|
|
id: comment
|
|
|
|
text: (root.modelData?.comment || root.modelData?.genericName || root.modelData?.name) ?? ""
|
|
font: Tokens.font.body.small
|
|
color: Colours.palette.m3outline
|
|
|
|
elide: Text.ElideRight
|
|
width: root.width - icon.width - favouriteIcon.width - Tokens.rounding.extraLargeIncreased
|
|
|
|
anchors.top: name.bottom
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
id: favouriteIcon
|
|
|
|
asynchronous: true
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
anchors.right: parent.right
|
|
active: root.modelData && Strings.testRegexList(GlobalConfig.launcher.favouriteApps, root.modelData.id)
|
|
|
|
sourceComponent: NsIcon {
|
|
icon: "favorite"
|
|
fill: 1
|
|
color: Colours.palette.m3primary
|
|
}
|
|
}
|
|
}
|
|
}
|