ffe90bd077
* lyrics: rewrite model * lyrics: cleanup code * lyrics: some minor layouting * lyrics: add fade shaders * lyrics: use appearance values from config * lyrics: formatting * lyrics: update readme * lyrics: fix jumping, redo netease backend (resused from another one of projects) * lyrics: fix netease searches, remove credit lines * lyrics: add RequestIds * lyrics: formatting * lyrics: lyricsDir path cleanup * lyrics: make empty lines not take up much space * lyrics: make empty lines not take up any space * Lyrics: Use QNetworkAccessManager instead of XMLHttpRequest also added ability to set request headers and ability to reset cookies for requests.cpp * lyrics: cleanup old code * lyrics: toggle lyrics by clicking the album art * lyrics: sanitize non-breaking spaces * lyrics: add a menu to select lyrics and manually search for them * lyrics: remove LrcLib backend * lyrics: change focus to when dashboard is opened instead of the lyricMenu * lyrics: improve UI * lyrics: improve UI more ig * lyrics: extract LyricsView and LyricMenu into separate components * lyrics: cleanup old files * lyrics: refactor LyricsService * lyrics: restore ComponentBehavior: Bound in lyrics components * lyrics: change SongID to real to fix integer overflow * lyrics: add animations to the lyricMenu * lyrics: fix manual search fields not auto updating * lyrics: fix jerks when switching tracks * lyrics: create lyrics directory if it doesn't exist * lyrics: silence logs, fix binding loops, fix index out of range errors * lyrics: only request keyboard focus when lyric menu is open * config: add option to enable/disable the lyrics * format + silence fileview errors * fix merge * anim and lsp fixes + format --------- Co-authored-by: 2 * r + 2 * t <61896496+soramanew@users.noreply.github.com>
106 lines
3.1 KiB
QML
106 lines
3.1 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import qs.components
|
|
import qs.components.filedialog
|
|
import qs.config
|
|
import qs.utils
|
|
import Caelestia
|
|
import Quickshell
|
|
import QtQuick
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property PersistentProperties visibilities
|
|
readonly property bool needsKeyboard: content.item?.needsKeyboard ?? false
|
|
readonly property PersistentProperties dashState: PersistentProperties {
|
|
property int currentTab
|
|
property date currentDate: new Date()
|
|
|
|
reloadableId: "dashboardState"
|
|
}
|
|
readonly property FileDialog facePicker: FileDialog {
|
|
title: qsTr("Select a profile picture")
|
|
filterLabel: qsTr("Image files")
|
|
filters: Images.validImageExtensions
|
|
onAccepted: path => {
|
|
if (CUtils.copyFile(Qt.resolvedUrl(path), Qt.resolvedUrl(`${Paths.home}/.face`)))
|
|
Quickshell.execDetached(["notify-send", "-a", "caelestia-shell", "-u", "low", "-h", `STRING:image-path:${path}`, "Profile picture changed", `Profile picture changed to ${Paths.shortenHome(path)}`]);
|
|
else
|
|
Quickshell.execDetached(["notify-send", "-a", "caelestia-shell", "-u", "critical", "Unable to change profile picture", `Failed to change profile picture to ${Paths.shortenHome(path)}`]);
|
|
}
|
|
}
|
|
|
|
readonly property real nonAnimHeight: state === "visible" ? (content.item?.nonAnimHeight ?? 0) : 0
|
|
|
|
visible: height > 0
|
|
implicitHeight: 0
|
|
implicitWidth: content.implicitWidth
|
|
|
|
onStateChanged: {
|
|
if (state === "visible" && timer.running) {
|
|
timer.triggered();
|
|
timer.stop();
|
|
}
|
|
}
|
|
|
|
states: State {
|
|
name: "visible"
|
|
when: root.visibilities.dashboard && Config.dashboard.enabled
|
|
|
|
PropertyChanges {
|
|
root.implicitHeight: content.implicitHeight
|
|
}
|
|
}
|
|
|
|
transitions: [
|
|
Transition {
|
|
from: ""
|
|
to: "visible"
|
|
|
|
Anim {
|
|
target: root
|
|
property: "implicitHeight"
|
|
duration: Appearance.anim.durations.expressiveDefaultSpatial
|
|
easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
|
|
}
|
|
},
|
|
Transition {
|
|
from: "visible"
|
|
to: ""
|
|
|
|
Anim {
|
|
target: root
|
|
property: "implicitHeight"
|
|
easing.bezierCurve: Appearance.anim.curves.emphasized
|
|
}
|
|
}
|
|
]
|
|
|
|
Timer {
|
|
id: timer
|
|
|
|
running: true
|
|
interval: Appearance.anim.durations.extraLarge
|
|
onTriggered: {
|
|
content.active = Qt.binding(() => (root.visibilities.dashboard && Config.dashboard.enabled) || root.visible);
|
|
content.visible = true;
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
id: content
|
|
|
|
anchors.horizontalCenter: parent.horizontalCenter
|
|
anchors.bottom: parent.bottom
|
|
|
|
visible: false
|
|
active: true
|
|
|
|
sourceComponent: Content {
|
|
visibilities: root.visibilities
|
|
state: root.dashState
|
|
facePicker: root.facePicker
|
|
}
|
|
}
|
|
}
|