118 lines
3.1 KiB
QML
118 lines
3.1 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
import Quickshell.Services.Pipewire
|
|
import Caelestia.Config
|
|
import qs.components
|
|
import qs.components.controls
|
|
import qs.services
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property PopoutState popouts
|
|
|
|
implicitWidth: layout.implicitWidth + Tokens.padding.medium * 2
|
|
implicitHeight: layout.implicitHeight + Tokens.padding.medium * 2
|
|
|
|
ButtonGroup {
|
|
id: sinks
|
|
}
|
|
|
|
ButtonGroup {
|
|
id: sources
|
|
}
|
|
|
|
ColumnLayout {
|
|
id: layout
|
|
|
|
anchors.left: parent.left
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
spacing: Tokens.spacing.normal
|
|
|
|
StyledText {
|
|
text: qsTr("Output device")
|
|
font.weight: 500
|
|
}
|
|
|
|
Repeater {
|
|
model: Audio.sinks
|
|
|
|
StyledRadioButton {
|
|
id: control
|
|
|
|
required property PwNode modelData
|
|
|
|
ButtonGroup.group: sinks
|
|
checked: Audio.sink?.id === modelData.id
|
|
onClicked: Audio.setAudioSink(modelData)
|
|
text: modelData.description
|
|
}
|
|
}
|
|
|
|
StyledText {
|
|
Layout.topMargin: Tokens.spacing.smaller
|
|
text: qsTr("Input device")
|
|
font.weight: 500
|
|
}
|
|
|
|
Repeater {
|
|
model: Audio.sources
|
|
|
|
StyledRadioButton {
|
|
required property PwNode modelData
|
|
|
|
ButtonGroup.group: sources
|
|
checked: Audio.source?.id === modelData.id
|
|
onClicked: Audio.setAudioSource(modelData)
|
|
text: modelData.description
|
|
}
|
|
}
|
|
|
|
StyledText {
|
|
Layout.topMargin: Tokens.spacing.smaller
|
|
Layout.bottomMargin: -Tokens.spacing.small / 2
|
|
text: qsTr("Volume (%1)").arg(Audio.muted ? qsTr("Muted") : `${Math.round(Audio.volume * 100)}%`)
|
|
font.weight: 500
|
|
}
|
|
|
|
CustomMouseArea {
|
|
Layout.fillWidth: true
|
|
implicitHeight: Tokens.padding.medium * 3
|
|
|
|
onWheel: event => {
|
|
if (event.angleDelta.y > 0)
|
|
Audio.incrementVolume();
|
|
else if (event.angleDelta.y < 0)
|
|
Audio.decrementVolume();
|
|
}
|
|
|
|
StyledSlider {
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
implicitHeight: parent.implicitHeight
|
|
|
|
value: Audio.volume
|
|
onMoved: Audio.setVolume(value)
|
|
|
|
Behavior on value {
|
|
Anim {}
|
|
}
|
|
}
|
|
}
|
|
|
|
IconTextButton {
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: Tokens.spacing.normal
|
|
inactiveColour: Colours.palette.m3primaryContainer
|
|
inactiveOnColour: Colours.palette.m3onPrimaryContainer
|
|
verticalPadding: Tokens.padding.extraSmall
|
|
text: qsTr("Open settings")
|
|
icon: "settings"
|
|
|
|
onClicked: root.popouts.detachRequested("audio")
|
|
}
|
|
}
|
|
}
|