116 lines
2.9 KiB
QML
116 lines
2.9 KiB
QML
pragma ComponentBehavior: Bound
|
|
|
|
import QtQuick
|
|
import Quickshell
|
|
import qs.components
|
|
import qs.services
|
|
import Caelestia.Config
|
|
|
|
Item {
|
|
id: root
|
|
|
|
required property ShellScreen screen
|
|
required property DrawerVisibilities visibilities
|
|
required property bool sidebarOrSessionVisible
|
|
|
|
property bool hovered
|
|
readonly property Brightness.Monitor monitor: Brightness.getMonitorForScreen(root.screen)
|
|
readonly property bool shouldBeActive: visibilities.osd && Config.osd.enabled && !(visibilities.utilities && Config.utilities.enabled)
|
|
property real offsetScale: shouldBeActive ? 0 : 1
|
|
property real sidebarOffset: sidebarOrSessionVisible ? 12 : 0
|
|
|
|
property real volume
|
|
property bool muted
|
|
property real sourceVolume
|
|
property bool sourceMuted
|
|
property real brightness
|
|
|
|
function show(): void {
|
|
visibilities.osd = true;
|
|
timer.restart();
|
|
}
|
|
|
|
Component.onCompleted: {
|
|
volume = Audio.volume;
|
|
muted = Audio.muted;
|
|
sourceVolume = Audio.sourceVolume;
|
|
sourceMuted = Audio.sourceMuted;
|
|
brightness = root.monitor?.brightness ?? 0;
|
|
}
|
|
|
|
visible: offsetScale < 1
|
|
anchors.rightMargin: (-implicitWidth - 5 - sidebarOffset) * offsetScale
|
|
implicitWidth: content.implicitWidth
|
|
implicitHeight: content.implicitHeight
|
|
opacity: 1 - offsetScale
|
|
|
|
Behavior on offsetScale {
|
|
Anim {
|
|
duration: Tokens.anim.durations.expressiveDefaultSpatial
|
|
easing: Tokens.anim.expressiveDefaultSpatial
|
|
}
|
|
}
|
|
|
|
Connections {
|
|
function onMutedChanged(): void {
|
|
root.show();
|
|
root.muted = Audio.muted;
|
|
}
|
|
|
|
function onVolumeChanged(): void {
|
|
root.show();
|
|
root.volume = Audio.volume;
|
|
}
|
|
|
|
function onSourceMutedChanged(): void {
|
|
root.show();
|
|
root.sourceMuted = Audio.sourceMuted;
|
|
}
|
|
|
|
function onSourceVolumeChanged(): void {
|
|
root.show();
|
|
root.sourceVolume = Audio.sourceVolume;
|
|
}
|
|
|
|
target: Audio
|
|
}
|
|
|
|
Connections {
|
|
function onBrightnessChanged(): void {
|
|
root.show();
|
|
root.brightness = root.monitor?.brightness ?? 0;
|
|
}
|
|
|
|
target: root.monitor
|
|
}
|
|
|
|
Timer {
|
|
id: timer
|
|
|
|
interval: Config.osd.hideDelay
|
|
onTriggered: {
|
|
if (!root.hovered)
|
|
root.visibilities.osd = false;
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
id: content
|
|
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
anchors.left: parent.left
|
|
|
|
asynchronous: true
|
|
active: root.shouldBeActive || root.visible
|
|
|
|
sourceComponent: Content {
|
|
monitor: root.monitor
|
|
visibilities: root.visibilities
|
|
volume: root.volume
|
|
muted: root.muted
|
|
sourceVolume: root.sourceVolume
|
|
sourceMuted: root.sourceMuted
|
|
brightness: root.brightness
|
|
}
|
|
}
|
|
}
|