28allday
83c6b62c13
Convert remaining reachable surfaces to NsIcon (launcher, utilities, windowinfo,
sidebar, dashboard, notification toast, shared controls IconTextButton/Menu/
SplitButton/ToggleButton/CollapsibleSection/CustomSpinBox, CoverArt). Handles
the `sourceComponent: MaterialIcon {` form and icon-via-alias controls.
- IconTextButton: alias -> plain `icon` property + bound NsIcon (cross-file alias
to a custom property was rejected).
- Reverted IconButton `font:` (the controls-wide font->fontStyle sweep wrongly
hit ButtonBase, which uses font not fontStyle).
- Glyphs map: +31 names (dashboard/utilities/launcher leftovers) — no "?" glyphs.
Old collapsed bar + old lock sub-components left as-is (unused, never render).
Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
122 lines
3.6 KiB
QML
122 lines
3.6 KiB
QML
import QtQuick
|
|
import QtQuick.Layouts
|
|
import Caelestia.Config
|
|
import qs.components
|
|
import qs.components.controls
|
|
import qs.services
|
|
|
|
StyledRect {
|
|
id: root
|
|
|
|
readonly property real nonAnimHeight: layout.implicitHeight + (IdleInhibitor.enabled ? activeChip.implicitHeight + activeChip.anchors.topMargin : 0) + Tokens.padding.extraLargeIncreased
|
|
|
|
Layout.fillWidth: true
|
|
implicitHeight: nonAnimHeight
|
|
|
|
radius: Tokens.rounding.large
|
|
color: Colours.tPalette.m3surfaceContainer
|
|
clip: true
|
|
|
|
RowLayout {
|
|
id: layout
|
|
|
|
anchors.top: parent.top
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
anchors.margins: Tokens.padding.large
|
|
spacing: Tokens.spacing.medium
|
|
|
|
StyledRect {
|
|
implicitWidth: implicitHeight
|
|
implicitHeight: icon.implicitHeight + Tokens.padding.large
|
|
|
|
radius: Tokens.rounding.full
|
|
color: IdleInhibitor.enabled ? Colours.palette.m3secondary : Colours.palette.m3secondaryContainer
|
|
|
|
NsIcon {
|
|
id: icon
|
|
|
|
anchors.centerIn: parent
|
|
icon: "coffee"
|
|
color: IdleInhibitor.enabled ? Colours.palette.m3onSecondary : Colours.palette.m3onSecondaryContainer
|
|
fontStyle: Tokens.font.icon.large
|
|
}
|
|
}
|
|
|
|
ColumnLayout {
|
|
Layout.fillWidth: true
|
|
spacing: 0
|
|
|
|
StyledText {
|
|
Layout.fillWidth: true
|
|
text: qsTr("Keep Awake")
|
|
font: Tokens.font.body.medium
|
|
elide: Text.ElideRight
|
|
}
|
|
|
|
StyledText {
|
|
Layout.fillWidth: true
|
|
text: IdleInhibitor.enabled ? qsTr("Preventing sleep mode") : qsTr("Normal power management")
|
|
color: Colours.palette.m3onSurfaceVariant
|
|
font: Tokens.font.body.small
|
|
elide: Text.ElideRight
|
|
}
|
|
}
|
|
|
|
StyledSwitch {
|
|
checked: IdleInhibitor.enabled
|
|
onToggled: IdleInhibitor.enabled = checked
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
id: activeChip
|
|
|
|
asynchronous: true
|
|
anchors.bottom: parent.bottom
|
|
anchors.left: parent.left
|
|
anchors.topMargin: Tokens.spacing.large
|
|
anchors.bottomMargin: IdleInhibitor.enabled ? Tokens.padding.large : -implicitHeight
|
|
anchors.leftMargin: Tokens.padding.large
|
|
|
|
opacity: IdleInhibitor.enabled ? 1 : 0
|
|
scale: IdleInhibitor.enabled ? 1 : 0.5
|
|
|
|
Component.onCompleted: active = Qt.binding(() => opacity > 0)
|
|
|
|
sourceComponent: StyledRect {
|
|
implicitWidth: activeText.implicitWidth + Tokens.padding.medium * 2
|
|
implicitHeight: activeText.implicitHeight + Tokens.padding.small
|
|
|
|
radius: Tokens.rounding.full
|
|
color: Colours.palette.m3primary
|
|
|
|
StyledText {
|
|
id: activeText
|
|
|
|
anchors.centerIn: parent
|
|
text: qsTr("Active since %1").arg(Qt.formatTime(IdleInhibitor.enabledSince, GlobalConfig.services.useTwelveHourClock ? "hh:mm a" : "hh:mm"))
|
|
color: Colours.palette.m3onPrimary
|
|
font: Tokens.font.body.builders.small.size(Math.round(Tokens.font.body.small.pointSize * 0.9)).build()
|
|
}
|
|
}
|
|
|
|
Behavior on anchors.bottomMargin {
|
|
Anim {}
|
|
}
|
|
|
|
Behavior on opacity {
|
|
Anim {
|
|
type: Anim.StandardSmall
|
|
}
|
|
}
|
|
|
|
Behavior on scale {
|
|
Anim {}
|
|
}
|
|
}
|
|
|
|
Behavior on implicitHeight {
|
|
Anim {}
|
|
}
|
|
}
|